#!/bin/csh

# Written in 1999 by Jim Phillips, Theoretical Biophysics Group,
# Beckman Institute, University of Illinois at Urbana-Champaign.

if ( $#argv < 1 ) then
  echo "Usage: $0 [from <first>] [to <last>] <file>"
  exit -1
endif

set titles = (`awk '/^ETITLE:/ { print; exit }' $argv[$#argv]`)

if ( $1 == from ) then
  shift argv
  set first_step = $1
  shift argv
else
  set first_step = 0
endif

if ( $1 == to ) then
  shift argv
  set last_step = $1
  shift argv
else
  set last_step = 0
endif

@ pos = 1
foreach t ( $titles )
  @ pos++
end

set file = $argv[1]

set open = '{'
set close = '}'
set dollar = '$'
set quote = '"'

#set tmpfile = /tmp/namdplot.$USER.$$.tmp
#touch tmpfile

set prog = ""

set prog = "$prog BEGIN $open"
@ pos = 1
set prog = "$prog n = 0;"
foreach t ( $titles )
  if ( $pos > 2 ) set prog = "$prog sum_$pos = 0.;"
  @ pos++
end
set prog = "$prog $close"

if ( $first_step ) then
  set prog = "$prog ${dollar}2 < $first_step $open next $close"
endif

if ( $last_step ) then
  set prog = "$prog ${dollar}2 > $last_step $open next $close"
endif

set prog = "$prog $open"
@ pos = 1
set prog = "$prog n+=1;"
foreach t ( $titles )
  if ( $pos > 2 ) set prog = "$prog sum_$pos+=$dollar$pos;"
  @ pos++
end
set prog = "$prog $close"

set prog = "$prog END $open"
@ pos = 1
set prog = "$prog print ${quote}N$quote, n;"
foreach t ( $titles )
  if ( $pos > 2 ) set prog = "$prog print $quote$t$quote, sum_$pos/n;"
  @ pos++
end
set prog = "$prog $close"

grep '^ENERGY:' $argv | grep -v '[a-z]' | awk "$prog"