#!/bin/csh

# Written in 1999 by Jim Phillips, Theoretical Biophysics Group,
# Beckman Institute, University of Illinois at Urbana-Champaign.

if ( $#argv < 1 ) then
  echo "Usage: $0 [from <first>] [to <last>] <file>"
  exit -1
endif

if ( $1 == from ) then
  shift argv
  set first_step = $1
  shift argv
else
  set first_step = 0
endif

if ( $1 == to ) then
  shift argv
  set last_step = $1
  shift argv
else
  set last_step = 0
endif

set file = $argv[1]

set open = '{'
set close = '}'
set dollar = '$'
set quote = '"'

set prog = ""

set prog = "$prog BEGIN $open"
@ pos = 3
set prog = "$prog n = 0;"
while ( $pos <= 11 )
  set prog = "$prog sum_$pos = 0.;"
  @ pos++
end
set prog = "$prog $close"

if ( $first_step ) then
  set prog = "$prog ${dollar}2 < $first_step $open next $close"
endif

if ( $last_step ) then
  set prog = "$prog ${dollar}2 > $last_step $open next $close"
endif

set prog = "$prog $open"
@ pos = 3
set prog = "$prog n+=1;"
while ( $pos <= 11 )
  set prog = "$prog sum_$pos+=$dollar$pos;"
  @ pos++
end
set prog = "$prog $close"

set prog = "$prog END $open"
set prog = "$prog print ${quote}N$quote, n;"
set prog = "$prog printf ${quote}%8.3f  %8.3f  %8.3f\n${quote}, sum_3/n, sum_4/n, sum_5/n;"
set prog = "$prog printf ${quote}%8.3f  %8.3f  %8.3f\n${quote}, sum_6/n, sum_7/n, sum_8/n;"
set prog = "$prog printf ${quote}%8.3f  %8.3f  %8.3f\n${quote}, sum_9/n, sum_10/n, sum_11/n;"
set prog = "$prog $close"

echo PRESSURE
grep '^PRESSURE:' $argv | grep -v '[a-z]' | awk "$prog"
echo GPRESSURE
grep '^GPRESSURE:' $argv | grep -v '[a-z]' | awk "$prog"
echo PRESSAVG
grep '^PRESSAVG:' $argv | grep -v '[a-z]' | awk "$prog"
echo GPRESSAVG
grep '^GPRESSAVG:' $argv | grep -v '[a-z]' | awk "$prog"